Oracle中DBMS_LOB包使用小结

本文主要介绍oracle数据库中dbms_lob包的使用以及使用dbms_lob包来维护lob数据库类型的基本方法。随着社会的发展,在现代信息系统的开发中,需要存储的已不仅仅是简单的文字信息,同时还包括一些图片和音像资料或者是超长的文本。比如开发一套旅游信息系统,每一个景点都有丰富的图片、音像资料和大量的文字介绍。这就要求后台数据库要有存储这些数据的能力。ORACLE公司在其Oracle8i中通过提供LOB字段实现了该功能。

在ORACLE数据库中,LOB大对象类型是用来存储大量的二进制和文本数据的一种数据类型(一个LOB字段可存储可多达4GB的数据)。目前,它又分为两种类型:内部LOB和外部LOB。内部LOB将数据以字节流的形式存储在数据库的内部。因而,内部LOB的许多操作都可以参与事务,也可以像处理普通数据一样对其进行备份和恢复操作。Oracle8i支持三种类型的内部LOB:BLOB(二进制数据)、CLOB(单字节字符数据)、NCLOB(多字节国家字符数据)。其中CLOB和NCLOB类型适用于存储超长的文本数据,BLOB字段适用于存储大量的二进制数据,如图像、视频、音频等。目前,Oracle8i只支持一种外部LOB类型,即BFILE类型。在数据库内,该类型仅存储数据在操作系统中的位置信息,而数据的实体以外部文件的形式存在于操作系统的文件系统中。因而,该类型所表示的数据是只读的,不参与事务。该类型可帮助用户管理大量的由外部程序访问的文件。

为了方便下文的叙述,我们假定使用如下语句在数据库中创建了一张表。

CREATE TABLE view_sites_info(
site_id NUMBER(3),
audio BLOB DEFAULT empty_blob(),
DOCUMENT CLOB DEFAULT empty_clob(),
video_file BFILE DEFAULT NULL,
CONSTRAINT PK_TAB_view_sites_info PRIMARY KEY (site_id));

ORACL提供了多种使用和维护LOB的方式,如使用PL/SQL DBMS_LOB包、调用OCI(Oracle Call Interface)、使用Proc*C/C++、使用JDBC等。其中最为方便有效的是使用PL/SQL调用DBMS_LOB包,本文就将介绍该方法。在Oracle中,存储在LOB中数据称为LOB的值,如使用Select对某一LOB字段进行选择,则返回的不是LOB的值,而是该LOB字段的定位器(可以理解为指向LOB值的指针)。如执行如下的SQL语句:

DECLARE
  audio_info BLOB;
BEGIN
  SELECT audio
    INTO audio_info
    FROM view_sites_info
   WHERE site_id = 100;
END;

存储在AUDIO_INFO变量中的就是LOB定位器,而不是LOB的值。而要对某一LOB的值进行访问和维护操作,必需通过其定位器来进行。DBMS_LOB包中提供的所有函数和过程都以LOB定位器作为参数。

DBMS_LOB包中主要提供了以下几个过程供用户对内部LOB字段进行维护:

APPEND:将源LOB中的内容加到目的LOB中。

CLOSE:关闭已经打开的LOB。

CREATETEMPORARY:在用户的临时表空间中,建立临时LOB。

FILECLOSE:关闭打开的BFILE定位符所指向的OS文件。

FILECLOSEALL:关闭当前会话已经打开的所有BFILE文件。

FILEEXISTS:确定file_loc对应的OS文件是否存在,1:存在。0:不存在。

FILEGETNAME:获取BFILE定位符所对应的目录别名和文件名。

FILEISOPEN:确定BFILE对应的OS文件是否打开。

FREETEMPORARY:释放在默认临时表空间中的临时LOB。

FILEOPEN:打开文件。

GETCHUNKSIZE:当建立包含CLOB/BLOB列的表时,通过指定CHUNK参数可以指定操纵LOB需要分配的字节数(数据库尺寸的整数倍)默认为数据块的尺寸。

COPY:从源LOB中复制数据到目的LOB。

ERASE:删除LOB中全部或部分内容。

TRIM:将LOB值减少到指定的长度。

WRITE:向LOB中写入数据。

INSTR:返回特定样式数据从LOB某偏移位置开始出现N次的具体位置。

IDOPEN:确定LOB是否打开,打开:1,未打开:0。

ISTEMPORARY:确定定位符是否为临时LOB。

LOADFROMFILE:将BFILE的部分或全部内容复制到目标LOB变量。

LOADBLOBFROMFILE:将BFILE数据装载到BLOB中,并且在装载后取得最新的偏移位置。

OPEN:打开LOB,open_mode(只读:dbms_lob.lob_readonly,写:dbms_lob.lob_readwrite)。

COMPARE:比较两个同种数据类型的LOB的部分或全部值是否相同。

GETLENGTH:获取LOB的长度。

READ:从LOB中读出数据。

SUBSTR:与字符处理函数SUBSTR使用方法一样。

WRITEAPPEND:将缓冲区数据写到LOB尾部。

下面我们以最为常用的读和写为例详细介绍这些过程的用法。首先介绍一下写过程。该过程的语法为:

PROCEDURE WRITE(lob_loc IN OUT BLOB,
                amount  IN BINARY_INTEGER,
                offset  IN INTEGER,
                buffer  IN RAW);
PROCEDURE WRITE(lob_loc IN OUT CLOB CHARACTER SET any_cs,
                amount  IN BINARY_INTEGER,
                offset  IN INTEGER,
                buffer  IN VARCHAR2 CHARACTER SET lob_loc%charset);

各参数的含义为:

lob_loc:要写入的LOB定位器。

amount:写入LOB中的字节数。

offset:指定开始操作的偏移量。

buffer:指定写操作的缓冲区。

下面的代码就是运用该过程向LOB字段写入数据的示例:

DECLARE
  lobloc CLOB;
  buffer VARCHAR2(2000);
  amount NUMBER := 20;
  offset NUMBER := 1;
BEGIN
  --初始化要写入的数据   
  buffer := 'This is a writing example';
  amount := length(buffer);
  SELECT document
    INTO lobloc --   获取定位器并锁定行   
    FROM view_sites_info
   WHERE site_id = 100
     FOR UPDATE;
  dbms_lob.write(lobloc,
                 amount,
                 1,
                 buffer);
  COMMIT;
END;

需要特别指出的是:

(1)在调用写过程前一定要使用SELECT语句检索到定位器且用FOR UPDATE子句锁定行,否则不能更新LOB。

(2)写过程从offset指定的位置开始,向LOB中写入长度为amount的数据,原LOB中在这个范围内的任何数据都将被覆盖。

(3)缓冲区的最大容量为32767字节,因此在写入大量数据时需多次调用该过程。

下面再来介绍一下读过程,该过程的语法为: 

PROCEDURE READ(lob_loc IN BLOB,
               amount  IN OUT BINARY_INTEGER,
               offset  IN INTEGER,
               buffer  OUT RAW);
PROCEDURE READ(lob_loc IN CLOB CHARACTER SET any_cs,
               amount  IN OUT BINARY_INTEGER,
               offset  IN INTEGER,
               buffer  OUT VARCHAR2 CHARACTER SET lob_loc%charset);

各参数的含义为:

lob_loc:要读取的LOB定位器。

amount:要读取的字节数。

offset:开始读取操作的偏移量。

buffer:存储读操作结果的缓冲区。 

下面的代码演示了如何使用该过程读取LOB字段中的数据:

DECLARE
  lobloc CLOB;
  buffer VARCHAR2(2000);
  amount NUMBER := 2;
  offset NUMBER := 6;
BEGIN
  SELECT document
    INTO lobloc --获取定位器   
    FROM lob_store
   WHERE lob_id = 100;
  dbms_lob.read(lobloc,
                amount,
                offset,
                buffer); --读取数据到缓冲区   
  dbms_output.put_line(buffer); --显示缓冲区中的数据   
  COMMIT;
END;

append存储过程用于将一个大对象添加到另一个大对象中,此时是将源大对象的内容全部添加过去。append存储过程的语法如下:

PROCEDURE append(dest_lob IN OUT NOCOPY BLOB,
                 src_lob  IN BLOB);
PROCEDURE append(dest_lob IN OUT NOCOPY CLOB CHARACTER SET any_cs,
                 src_lob  IN CLOB CHARACTER SET dest_lob%charset);

其中,各个参数的含义如下:

dest_lob是被源lob添加到的目标lob的定位器。

src_lob是源lob的定位器。

any_cs用来指定字符集。

参考资料:

1. DBMS_LOB包使用和维护

本文标题:Oracle中DBMS_LOB包使用小结

本文链接:http://yedward.net/?id=164

本文版权归作者所有,欢迎转载,转载请以文字链接的形式注明文章出处。

相关文章